Gateway IPv4 - Virtual Private Cloud - Alibaba Cloud Documentation Center

Secara default, resource VPC yang memiliki alamat IP publik dapat berkomunikasi langsung dengan Internet melalui IPv4. Di lingkungan enterprise, metode akses Internet yang tidak terkelola—seperti tim bisnis yang menetapkan alamat IP publik ke instance ECS tanpa persetujuan—membawa risiko keamanan. Gateway IPv4 memungkinkan Anda mengarahkan seluruh traffic yang menuju Internet melalui satu titik kendali menggunakan tabel rute, sehingga mengurangi risiko keamanan akibat akses yang terdesentralisasi.

Mengapa menggunakan gateway IPv4

Perbandingan	Akses Internet langsung (default VPC)	Kontrol terpusat dengan gateway IPv4
Contoh	Tanpa gateway IPv4, instance ECS mengakses Internet secara langsung melalui alamat IP publik statis, EIP, atau gateway NAT Internet.	Manajemen terpusat untuk seluruh traffic akses Internet.
Kasus penggunaan	Hanya sejumlah kecil instance ECS yang memerlukan akses Internet langsung dan independen. Ideal jika kebutuhan akses Internet sering berubah.	Arsitektur jaringan skala besar dan multi-tier. Lingkungan enterprise dengan persyaratan keamanan jaringan dan kepatuhan yang ketat.
Kompleksitas	Sederhana dan cepat. Tidak perlu konfigurasi rute.	Memerlukan perencanaan jaringan dan konfigurasi aturan rute.
Fleksibilitas	Setiap instans dikelola secara independen tanpa memengaruhi instans lainnya.	Perubahan kebijakan jaringan memengaruhi semua instans dalam VPC.
Keamanan	Keamanan bergantung terutama pada aturan grup keamanan yang dikonfigurasi untuk setiap instans.	Gateway IPv4 memberlakukan kebijakan jaringan yang konsisten di seluruh VPC melalui kontrol terpusat.

Perbedaan antara gateway IPv4 dan gateway NAT Internet

Gateway IPv4 dan gateway NAT Internet dapat digunakan bersamaan. Lihat Akses Internet untuk detail tentang hubungan antar komponen jaringan ini.

Komponen	Gateway IPv4	Gateway NAT Internet
Tujuan	Komponen batas VPC yang mengontrol traffic IPv4 publik	Perangkat Translasi Alamat Jaringan (NAT) di dalam VPC
Skenario	Kontrol terpusat atas traffic akses Internet	Egress terpadu untuk traffic yang menuju Internet
Menyediakan akses Internet	Tidak. Hanya mengontrol traffic.	Menyediakan akses Internet dengan mengasosiasikan EIP (EIP menyediakan konektivitas; gateway NAT itu sendiri tidak menyediakan akses Internet.)

Setelah membuat gateway IPv4, vSwitch terbagi menjadi dua kategori:

vSwitch publik: Tabel rute terkait berisi entri rute dengan Destination CIDR Block diatur ke 0.0.0.0/0 dan Next Hop diatur ke gateway IPv4. Resource dalam vSwitch ini dapat mengakses Internet setelah mengasosiasikan alamat IP publik.
vSwitch privat: Tabel rute terkait tidak berisi rute yang mengarah ke gateway IPv4. Resource dalam vSwitch ini tidak dapat mengakses Internet secara langsung meskipun memiliki alamat IP publik.

Saat menggunakan gateway NAT Internet bersama gateway IPv4, deploy gateway NAT Internet di vSwitch publik. Instance ECS di vSwitch privat harus memiliki rute yang mengarah ke gateway NAT Internet agar traffic-nya yang menuju Internet dialirkan melalui gateway NAT tersebut, yang menggunakan alamat IP publik terkaitnya untuk mencapai Internet. Perhatikan hal berikut:

Pastikan EipBindMode gateway NAT Internet diatur ke mode NAT agar kompatibel dengan gateway IPv4.
- Gateway NAT Internet yang dibuat melalui konsol secara default menggunakan mode NAT. Saat memanggil CreateNatGateway, atur EipBindMode ke NAT. Setelah pembuatan, panggil ModifyNatGatewayAttribute untuk mengubah EipBindMode.
- Jika sudah ada gateway NAT Internet dengan EipBindMode diatur ke mode MULTI_BINDED, maka gateway tersebut tidak kompatibel dengan gateway IPv4, dan Anda tidak dapat membuat gateway IPv4.
- Jika gateway IPv4 sudah ada dan Anda memanggil CreateNatGateway untuk membuat gateway NAT Internet dengan EipBindMode diatur ke mode MULTI_BINDED, Anda tidak dapat mengasosiasikan EIP ke gateway NAT tersebut.
Untuk mencegah resource di vSwitch privat kehilangan akses Internet setelah gateway IPv4 diaktifkan, lengkapi konfigurasi rute sebelum aktivasi.

Cara kerja

Kontrol akses Internet dengan gateway IPv4

Setelah membuat dan mengaktifkan gateway IPv4 untuk VPC, gateway tersebut secara terpusat mengontrol seluruh traffic akses Internet. Hanya vSwitch yang tabel rutanya berisi rute yang mengarah ke gateway IPv4 yang dapat mengakses Internet secara langsung. Di halaman detail VPC, periksa IPv4 Internet Access Mode untuk memverifikasi apakah gateway IPv4 sedang aktif mengontrol traffic Internet.

Sebelum aktivasi, traffic Internet di VPC tidak terpengaruh. Namun, gangguan jaringan singkat mungkin terjadi selama aktivasi karena peralihan jalur traffic.

Hapus gateway IPv4

Sebelum penghapusan, lepaskan asosiasi tabel rute gateway. Di kolom Actions gateway IPv4 target, klik Delete, atau panggil DeleteIpv4Gateway. Mode penghapusan yang Anda pilih menentukan cara VPC menangani akses Internet setelahnya.

Mode publik: Sistem secara otomatis menghapus semua entri rute yang mengarah ke gateway IPv4. VPC kembali ke kondisi awal, di mana instans dengan alamat IP publik dapat mengakses Internet secara langsung.
Mode privat: Anda harus terlebih dahulu menghapus secara manual semua entri rute yang mengarah ke gateway IPv4 dari tabel rute. Setelah penghapusan, semua resource VPC kehilangan akses Internet. Untuk memulihkan akses Internet langsung, buat gateway IPv4 baru dan hapus dalam mode publik.
Penting
Setelah penghapusan dalam mode privat, semua resource VPC kehilangan akses Internet terlepas dari apakah mereka memiliki alamat IP publik atau tidak. Lakukan dengan hati-hati.

Kontrol akses Internet secara terpusat

Di lingkungan enterprise, metode akses Internet yang tidak terkelola—seperti tim bisnis yang menetapkan alamat IP publik ke instance ECS tanpa persetujuan—menyulitkan tim operasional dalam memberlakukan kebijakan yang konsisten. Gunakan gateway IPv4 untuk memusatkan kontrol akses Internet, sehingga mengurangi risiko keamanan akibat akses yang terdesentralisasi.

Konsol

Buka halaman Konsol VPC - Gateway IPv4. Pilih wilayah tempat VPC Anda di-deploy, lalu klik Create IPv4 Gateway.
Create IPv4 gateway: Pilih VPC yang ingin Anda pusatkan kontrol akses Internet-nya.
Activate IPv4 gateway: Pilih tabel rute yang terkait dengan vSwitch publik. Sistem secara otomatis menambahkan rute 0.0.0.0/0 yang mengarah ke gateway IPv4, memastikan resource di vSwitch publik dapat mengakses Internet setelah mengasosiasikan alamat IP publik. Jika tabel rute sudah berisi rute 0.0.0.0/0, klik Activate Later, perbarui lompatan berikutnya dari rute tersebut ke gateway IPv4, lalu aktifkan. Setelah aktivasi, akses Internet VPC dikontrol oleh gateway IPv4.
- Jika instance ECS menggunakan gateway NAT Internet untuk akses Internet, deploy instance ECS dan gateway NAT tersebut di vSwitch yang berbeda. Tambahkan rute 0.0.0.0/0 yang mengarah ke gateway IPv4 di tabel rute yang terkait dengan vSwitch gateway NAT. Tambahkan rute yang mengarah ke gateway NAT di vSwitch publik pada tabel rute yang terkait dengan vSwitch instance ECS.
- Jika instance ECS menggunakan alamat IP publik statis atau EIP yang diasosiasikan langsung, tambahkan rute 0.0.0.0/0 yang mengarah ke gateway IPv4.

API

Panggil CreateIpv4Gateway untuk membuat gateway IPv4.
Panggil EnableVpcIpv4Gateway untuk mengaktifkan gateway IPv4. Atur RouteTableList ke tabel rute yang terkait dengan vSwitch publik. Jika diabaikan, panggil CreateRouteEntry untuk menambahkan secara manual rute 0.0.0.0/0 yang mengarah ke gateway IPv4.

Terraform

Berbeda dengan konsol, mengaktifkan gateway IPv4 melalui Terraform tidak secara otomatis menambahkan rute 0.0.0.0/0 yang mengarah ke gateway IPv4. Anda harus mengonfigurasi rute tersebut secara manual.

Resource: alicloud_vpc, alicloud_vswitch, alicloud_vpc_ipv4_gateway, alicloud_route_table, alicloud_route_table_attachment, alicloud_vpc_route_entry, alicloud_instance, alicloud_security_group, alicloud_security_group_rule, alicloud_eip_address, alicloud_eip_association, alicloud_nat_gateway, alicloud_snat_entry

Data Sources: alicloud_zones

# Tentukan wilayah untuk gateway IPv4
provider "alicloud" {
  region = "cn-hangzhou"
}

# Dapatkan zona yang mendukung pembuatan vSwitch secara otomatis
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # Kueri zona yang tersedia untuk resource VPC
}

# Buat VPC 
resource "alicloud_vpc" "example_vpc" {
  vpc_name   = "example_vpc_name"
  cidr_block = "10.0.0.0/16" # Tentukan blok CIDR 
}

# Definisikan konfigurasi vSwitch
locals {
  vswitches = {
    vsw1 = {
      name       = "example_vsw1_name"
      cidr_block = "10.0.0.0/24"
      zone_index = 0
    }
    vsw2 = {
      name       = "example_vsw2_name"
      cidr_block = "10.0.1.0/24"
      zone_index = 1
    }
    vsw3 = {
      name       = "example_vsw3_name"
      cidr_block = "10.0.2.0/24"
      zone_index = 0
    }
    vsw4 = {
      name       = "example_vsw4_name"
      cidr_block = "10.0.3.0/24"
      zone_index = 0
    }
  }

  # Definisikan konfigurasi tabel rute
  route_tables = {
    rt1 = {
      name        = "example_rt1_name"
      vswitch_key = "vsw1"
    }
    rt2 = {
      name        = "example_rt2_name"
      vswitch_key = "vsw2"
    }
    rt3 = {
      name        = "example_rt3_name"
      vswitch_key = "vsw3"
    }
    rt4 = {
      name        = "example_rt4_name"
      vswitch_key = "vsw4"
    }
  }

  # Definisikan konfigurasi instans
  instances = {
    instance1 = {
      name        = "example_instance1_name"
      vswitch_key = "vsw1"
    }
    instance2 = {
      name        = "example_instance2_name"
      vswitch_key = "vsw3"
    }
    instance3 = {
      name        = "example_instance3_name"
      vswitch_key = "vsw4"
    }
  }

  # Definisikan konfigurasi EIP
  eips = {
    eip1 = {
      name = "example_eip1_name"
    }
    eip2 = {
      name = "example_eip2_name"
    }
  }

  # Definisikan konfigurasi entri SNAT
  snat_entries = {
    snat1 = {
      instance_key = "instance2"
    }
    snat2 = {
      instance_key = "instance3"
    }
  }
}

# Buat beberapa vSwitch
resource "alicloud_vswitch" "example_vsw" {
  for_each = local.vswitches

  vswitch_name = each.value.name
  cidr_block   = each.value.cidr_block
  vpc_id       = alicloud_vpc.example_vpc.id
  zone_id      = data.alicloud_zones.available_zones.zones[each.value.zone_index].id
}

# Buat beberapa tabel rute kustom
resource "alicloud_route_table" "example_route_table" {
  for_each = local.route_tables

  route_table_name = each.value.name
  vpc_id           = alicloud_vpc.example_vpc.id
}

# Asosiasikan tabel rute dengan vSwitch
resource "alicloud_route_table_attachment" "example_route_table_attachment" {
  for_each = local.route_tables

  vswitch_id     = alicloud_vswitch.example_vsw[each.value.vswitch_key].id
  route_table_id = alicloud_route_table.example_route_table[each.key].id
}

# Tentukan tipe instans
variable "instance_type" {
  default = "ecs.e-c1m1.large"
}

# Tentukan ID image
variable "image_id" {
  default = "aliyun_3_x64_20G_alibase_20221102.vhd"
}

# Buat grup keamanan
resource "alicloud_security_group" "example_security_group" {
  security_group_name = "example_security_group_name"
  vpc_id              = alicloud_vpc.example_vpc.id
}

# Buat aturan grup keamanan. Sesuaikan protokol dan port sesuai kebutuhan.
resource "alicloud_security_group_rule" "allow_internet" {
  type              = "ingress"
  ip_protocol       = "icmp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "-1/-1"
  priority          = 1
  security_group_id = alicloud_security_group.example_security_group.id
  cidr_ip           = "0.0.0.0/0"
}

# Buat beberapa instance ECS
resource "alicloud_instance" "example_instance" {
  for_each = local.instances

  instance_name        = each.value.name
  vswitch_id           = alicloud_vswitch.example_vsw[each.value.vswitch_key].id
  instance_type        = var.instance_type
  image_id             = var.image_id
  system_disk_category = "cloud_essd"
  security_groups      = [alicloud_security_group.example_security_group.id]
  instance_charge_type = "PostPaid"           # Penagihan pay-as-you-go
  spot_strategy        = "SpotWithPriceLimit" # Instans spot dengan batas harga
}

# Buat beberapa EIP
resource "alicloud_eip_address" "example_eip" {
  for_each = local.eips

  address_name = each.value.name
  isp          = "BGP"
  netmode      = "public"
  bandwidth    = "1"
  payment_type = "PayAsYouGo"
}

# Asosiasikan instance ECS dengan EIP
resource "alicloud_eip_association" "example_eip_ecs_association" {
  allocation_id = alicloud_eip_address.example_eip["eip1"].id
  instance_type = "EcsInstance"
  instance_id   = alicloud_instance.example_instance["instance1"].id
}

# Buat gateway NAT Internet
resource "alicloud_nat_gateway" "example_natgw" {
  nat_gateway_name = "example_natgw_name"
  vpc_id           = alicloud_vpc.example_vpc.id
  vswitch_id       = alicloud_vswitch.example_vsw["vsw2"].id
  nat_type         = "Enhanced"
  eip_bind_mode    = "NAT" # Mode binding EIP harus NAT
  payment_type     = "PayAsYouGo"
}

# Asosiasikan EIP dengan gateway NAT Internet
resource "alicloud_eip_association" "example_eip_natgw_association" {
  allocation_id = alicloud_eip_address.example_eip["eip2"].id
  instance_type = "NAT"
  instance_id   = alicloud_nat_gateway.example_natgw.id
}

# Tambahkan rute yang mengarah ke gateway NAT
resource "alicloud_route_entry" "example_rt3_route" {
  route_table_id        = alicloud_route_table.example_route_table["rt3"].id
  destination_cidrblock = "0.0.0.0/0"
  nexthop_type          = "NatGateway"
  nexthop_id            = alicloud_nat_gateway.example_natgw.id
}

# Tambahkan rute yang mengarah ke gateway NAT
resource "alicloud_route_entry" "example_rt4_route" {
  route_table_id        = alicloud_route_table.example_route_table["rt4"].id
  destination_cidrblock = "0.0.0.0/0"
  nexthop_type          = "NatGateway"
  nexthop_id            = alicloud_nat_gateway.example_natgw.id
}

# Buat entri SNAT
resource "alicloud_snat_entry" "example_snat_entry" {
  for_each = local.snat_entries

  snat_table_id = alicloud_nat_gateway.example_natgw.snat_table_ids
  source_cidr   = alicloud_instance.example_instance[each.value.instance_key].primary_ip_address
  snat_ip       = alicloud_eip_address.example_eip["eip2"].ip_address
}

# Buat gateway IPv4
resource "alicloud_vpc_ipv4_gateway" "example_ipv4gw" {
  ipv4_gateway_name = "example_ipv4gw_name"
  vpc_id            = alicloud_vpc.example_vpc.id
  enabled           = true
}

# Tambahkan rute yang mengarah ke gateway IPv4
resource "alicloud_route_entry" "example_rt1_route" {
  route_table_id        = alicloud_route_table.example_route_table["rt1"].id
  destination_cidrblock = "0.0.0.0/0"
  nexthop_type          = "Ipv4Gateway"
  nexthop_id            = alicloud_vpc_ipv4_gateway.example_ipv4gw.id
}

# Tambahkan rute yang mengarah ke gateway IPv4
resource "alicloud_route_entry" "example_rt2_route" {
  route_table_id        = alicloud_route_table.example_route_table["rt2"].id
  destination_cidrblock = "0.0.0.0/0"
  nexthop_type          = "Ipv4Gateway"
  nexthop_id            = alicloud_vpc_ipv4_gateway.example_ipv4gw.id
}

Blok CIDR publik yang digunakan secara privat

VPC secara default menggunakan blok CIDR privat RFC 1918: 10.0.0.0/8, 172.16.0.0/12, dan 192.168.0.0/16. Ketika VPC terhubung ke pusat data lokal atau VPC lain yang menggunakan blok CIDR non-RFC 1918 (misalnya, 30.0.0.0/16), resource cloud dengan akses Internet mengirim permintaan ke blok non-standar tersebut melalui Internet publik, bukan mengikuti rute privat yang telah dikonfigurasi.

Setelah membuat dan mengaktifkan gateway IPv4, gateway tersebut secara terpusat mengontrol akses Internet dan seluruh traffic diteruskan berdasarkan tabel rute. vSwitch harus memiliki rute 0.0.0.0/0 yang mengarah ke gateway IPv4 agar resource-nya dapat mengakses Internet. Berdasarkan aturan pencocokan awalan terpanjang, traffic yang ditujukan ke ECS02 akan sesuai dengan rute 30.0.0.0/16 dan diteruskan ke VPC peer, bukan melalui Internet.

Konsol

Buka halaman Konsol VPC - Gateway IPv4. Pilih wilayah tempat VPC Anda di-deploy, lalu klik Create IPv4 Gateway.
Create IPv4 gateway: Pilih VPC yang perlu mengakses blok CIDR privat non-standar.
Activate IPv4 gateway: Pilih tabel rute yang terkait dengan vSwitch yang perlu mengakses blok CIDR privat non-standar. Sistem secara otomatis menambahkan rute 0.0.0.0/0 yang mengarah ke gateway IPv4, memungkinkan resource di vSwitch tersebut mencapai blok CIDR non-standar melalui rute yang lebih spesifik.
- Pastikan tabel rute belum berisi rute 0.0.0.0/0. Jika sudah ada, klik Activate Later, hapus rute tersebut, lalu aktifkan.
- Setelah aktivasi, gateway IPv4 secara terpusat mengontrol akses Internet dan seluruh traffic diteruskan berdasarkan tabel rute.

API

Panggil CreateIpv4Gateway untuk membuat gateway IPv4.
Panggil EnableVpcIpv4Gateway untuk mengaktifkannya. Atur RouteTableList ke tabel rute yang terkait dengan vSwitch publik. Jika diabaikan, panggil CreateRouteEntry untuk menambahkan secara manual rute 0.0.0.0/0 yang mengarah ke gateway IPv4.

Terraform

Resource: alicloud_vpc, alicloud_vswitch, alicloud_vpc_ipv4_gateway, alicloud_route_table, alicloud_route_table_attachment, alicloud_vpc_route_entry, alicloud_instance, alicloud_security_group, alicloud_security_group_rule, alicloud_eip_address, alicloud_eip_association, alicloud_vpc_peer_connection

Data Sources: alicloud_zones

Dalam contoh ini, VPC dalam koneksi peering dimiliki oleh akun yang sama. Untuk koneksi peering lintas akun, buat juga alicloud_vpc_peer_connection_accepter agar akun peer menerima permintaan koneksi.

# Tentukan wilayah untuk gateway IPv4
provider "alicloud" {
  region = "cn-hangzhou"
}

# Dapatkan zona yang mendukung pembuatan vSwitch secara otomatis
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # Kueri zona yang tersedia untuk resource VPC
}

# Tentukan tipe instans
variable "instance_type" {
  default = "ecs.e-c1m1.large"
}

# Tentukan ID image
variable "image_id" {
  default = "aliyun_3_x64_20G_alibase_20221102.vhd"
}

# Buat VPC
resource "alicloud_vpc" "example_vpc1" {
  vpc_name   = "example_vpc1_name"
  cidr_block = "10.0.0.0/16" # Tentukan blok CIDR 
}

# Buat VPC
resource "alicloud_vpc" "example_vpc2" {
  vpc_name   = "example_vpc2_name"
  cidr_block = "30.0.0.0/16" # Tentukan blok CIDR 
}

# Buat vSwitch
resource "alicloud_vswitch" "example_vsw1" {
  vswitch_name = "example_vsw1_name"
  cidr_block   = "10.0.1.0/24"
  vpc_id       = alicloud_vpc.example_vpc1.id
  zone_id      = data.alicloud_zones.available_zones.zones.0.id
}

# Buat vSwitch
resource "alicloud_vswitch" "example_vsw2" {
  vswitch_name = "example_vsw2_name"
  cidr_block   = "30.0.1.0/24"
  vpc_id       = alicloud_vpc.example_vpc2.id
  zone_id      = data.alicloud_zones.available_zones.zones.1.id
}

# Buat grup keamanan
resource "alicloud_security_group" "example_security_group1" {
  security_group_name = "example_security_group1_name"
  vpc_id              = alicloud_vpc.example_vpc1.id
}

# Buat aturan grup keamanan. Sesuaikan protokol dan port sesuai kebutuhan.
resource "alicloud_security_group_rule" "allow_internet1" {
  type              = "ingress"
  ip_protocol       = "icmp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "-1/-1"
  priority          = 1
  security_group_id = alicloud_security_group.example_security_group1.id
  cidr_ip           = "0.0.0.0/0"
}

# Buat grup keamanan
resource "alicloud_security_group" "example_security_group2" {
  security_group_name = "example_security_group2_name"
  vpc_id              = alicloud_vpc.example_vpc2.id
}

# Buat aturan grup keamanan. Sesuaikan protokol dan port sesuai kebutuhan.
resource "alicloud_security_group_rule" "allow_internet2" {
  type              = "ingress"
  ip_protocol       = "icmp"
  nic_type          = "intranet"
  policy            = "accept"
  port_range        = "-1/-1"
  priority          = 1
  security_group_id = alicloud_security_group.example_security_group2.id
  cidr_ip           = "0.0.0.0/0"
}

# Buat instance ECS
resource "alicloud_instance" "example_instance1" {
  instance_name        = "example_instance1_name"
  vswitch_id           = alicloud_vswitch.example_vsw1.id
  instance_type        = var.instance_type
  image_id             = var.image_id
  system_disk_category = "cloud_essd"
  security_groups      = [alicloud_security_group.example_security_group1.id]
  instance_charge_type = "PostPaid"
  spot_strategy        = "SpotWithPriceLimit"
}

# Buat EIP
resource "alicloud_eip_address" "example_eip" {
  address_name = "example_eip_name"
  isp          = "BGP"
  netmode      = "public"
  bandwidth    = "1"
  payment_type = "PayAsYouGo"
}

# Asosiasikan instance ECS dengan EIP
resource "alicloud_eip_association" "example_eip_ecs_association" {
  allocation_id = alicloud_eip_address.example_eip.id
  instance_type = "EcsInstance"
  instance_id   = alicloud_instance.example_instance1.id
}

# Buat instance ECS
resource "alicloud_instance" "example_instance2" {
  instance_name        = "example_instance2_name"
  vswitch_id           = alicloud_vswitch.example_vsw2.id
  instance_type        = var.instance_type
  image_id             = var.image_id
  system_disk_category = "cloud_essd"
  security_groups      = [alicloud_security_group.example_security_group2.id]
  instance_charge_type = "PostPaid"
  spot_strategy        = "SpotWithPriceLimit"
}

# Buat tabel rute kustom
resource "alicloud_route_table" "example_route_table1" {
  route_table_name = "example_route_table1_name"
  vpc_id           = alicloud_vpc.example_vpc1.id
}

# Asosiasikan tabel rute dengan vSwitch
resource "alicloud_route_table_attachment" "example_route_table_attachment1" {
  vswitch_id     = alicloud_vswitch.example_vsw1.id
  route_table_id = alicloud_route_table.example_route_table1.id
}

# Buat tabel rute kustom
resource "alicloud_route_table" "example_route_table2" {
  route_table_name = "example_route_table2_name"
  vpc_id           = alicloud_vpc.example_vpc2.id
}

# Asosiasikan tabel rute dengan vSwitch
resource "alicloud_route_table_attachment" "example_route_table_attachment2" {
  vswitch_id     = alicloud_vswitch.example_vsw2.id
  route_table_id = alicloud_route_table.example_route_table2.id
}

# Buat koneksi peering VPC
resource "alicloud_vpc_peer_connection" "example_vpc_peer" {
  peer_connection_name = "example_vpc_peer_name"
  vpc_id               = alicloud_vpc.example_vpc1.id
  accepting_ali_uid    = "1234****" # ID akun pemilik VPC peer. Contoh ini membuat koneksi peering dalam satu akun. Untuk peering lintas akun, buat alicloud_vpc_peer_connection_accepter agar akun peer menerima permintaan.
  accepting_region_id  = "cn-hangzhou"
  accepting_vpc_id     = alicloud_vpc.example_vpc2.id
}

# Konfigurasikan rute untuk koneksi peering
resource "alicloud_route_entry" "example_peer_route1" {
  route_table_id        = alicloud_route_table.example_route_table1.id
  destination_cidrblock = "30.0.0.0/16"
  nexthop_type          = "VpcPeer"
  nexthop_id            = alicloud_vpc_peer_connection.example_vpc_peer.id
}

# Konfigurasikan rute untuk koneksi peering
resource "alicloud_route_entry" "example_peer_route2" {
  route_table_id        = alicloud_route_table.example_route_table2.id
  destination_cidrblock = "10.0.0.0/16"
  nexthop_type          = "VpcPeer"
  nexthop_id            = alicloud_vpc_peer_connection.example_vpc_peer.id
}

# Buat gateway IPv4
resource "alicloud_vpc_ipv4_gateway" "example_ipv4gw" {
  ipv4_gateway_name = "example_ipv4gw_name"
  vpc_id            = alicloud_vpc.example_vpc1.id
  enabled           = true
}

# Tambahkan rute yang mengarah ke gateway IPv4
resource "alicloud_route_entry" "example_igw_route" {
  route_table_id        = alicloud_route_table.example_route_table1.id
  destination_cidrblock = "0.0.0.0/0"
  nexthop_type          = "Ipv4Gateway"
  nexthop_id            = alicloud_vpc_ipv4_gateway.example_ipv4gw.id
}

Pengalihan lalu lintas Internet inbound (perangkat keamanan pihak ketiga)

Gateway IPv4 hanya dapat mengontrol secara terpusat lalu lintas Internet arah keluar. Untuk lalu lintas inbound yang masuk ke VPC, asosiasikan tabel rute gateway dengan gateway IPv4 untuk mengalihkan lalu lintas inbound ke perangkat keamanan guna inspeksi dan penyaringan mendalam, mencegah serangan berbahaya dan akses tidak sah. Dikombinasikan dengan tabel rute kustom, Anda juga dapat mengalihkan lalu lintas outbound ke perangkat keamanan untuk perlindungan inbound dan outbound yang komprehensif.

Gateway IPv4 hanya dapat diasosiasikan dengan tabel rute gateway (tabel rute tipe gerbang batas). Setiap VPC hanya mendukung satu gateway IPv4 dan satu tabel rute gateway, dengan ikatan satu-ke-satu.

Untuk mengonfigurasi pengalihan lalu lintas inbound, ubah entri rute sistem di tabel rute gateway dan atur lompatan berikutnya dari blok CIDR vSwitch target ke perangkat keamanan. Tabel rute gateway tidak mendukung pembuatan rute kustom melalui Add Route Entry.

Arsitektur titik tunggal

Arsitektur ketersediaan tinggi GWLB

Dalam arsitektur titik tunggal, kegagalan perangkat keamanan memengaruhi ketersediaan seluruh sistem Anda. Deploy perangkat keamanan di belakang Gateway Load Balancer (GWLB) untuk ketersediaan tinggi dan menghilangkan titik kegagalan tunggal.

Jalur lalu lintas Internet IPv4 inbound

Jalur lalu lintas Internet IPv4 outbound

1. Traffic IPv4 masuk ke VPC bisnis melalui gateway IPv4.

2. Tabel rute gateway mengarahkan traffic ke GWLBe.

3. GWLBe meneruskan traffic ke GWLB, yang mendistribusikannya ke perangkat keamanan.

4. Setelah inspeksi, traffic kembali ke GWLB, lalu ke GWLBe melalui PrivateLink.

5. Tabel rute untuk subnet GWLBe meneruskan traffic ke server bisnis.

1. Tabel rute untuk subnet server bisnis mengarahkan traffic ke GWLBe.

2. GWLBe meneruskan traffic ke GWLB, yang mendistribusikannya ke perangkat keamanan.

3. Setelah inspeksi, traffic kembali ke GWLB, lalu ke GWLBe melalui PrivateLink.

4. Tabel rute untuk subnet GWLBe meneruskan traffic ke gateway IPv4.

5. Gateway IPv4 meneruskan traffic ke Internet.

Untuk mengonfigurasi tabel rute gateway: temukan rute sistem untuk blok CIDR vSwitch target, klik Edit di kolom Actions, dan atur lompatan berikutnya ke GWLBe. Setelah disimpan, entri rute tersebut muncul di tab Custom Route.

Konsol

Asosiasikan tabel rute gateway

Di halaman detail gateway IPv4 target, klik Bind. Atau, di tab Associated Border Gateway di halaman detail tabel rute gateway target, klik Associate Border Gateway dan pilih gateway IPv4 target.

Lepaskan asosiasi tabel rute gateway

Di halaman detail gateway IPv4 target, atau di tab Associated Border Gateway di halaman detail tabel rute gateway target, klik Unbind.

API

Panggil AssociateRouteTableWithGateway untuk mengasosiasikan tabel rute gateway.
Panggil DissociateRouteTableFromGateway untuk melepaskan asosiasi tabel rute gateway.

Terraform

Resource: alicloud_vpc_gateway_route_table_attachment

# Tentukan wilayah tempat gateway IPv4 di-deploy
provider "alicloud" {
  region = "cn-hangzhou"
}

# Tentukan ID gateway IPv4
variable "ipv4_gateway_id" {
  default = "ipv4gw-hp3v******" # Ganti dengan ID gateway IPv4 yang sebenarnya
}

# Tentukan ID tabel rute gateway
variable "route_table_id" {
  default = "vtb-hp3w******" # Ganti dengan ID tabel rute gateway yang sebenarnya
}

# Asosiasikan tabel rute gateway
resource "alicloud_vpc_gateway_route_table_attachment" "example_attachment" {
  ipv4_gateway_id = var.ipv4_gateway_id
  route_table_id  = var.route_table_id
}

Informasi tambahan

Batasan

Setiap VPC hanya mendukung satu gateway IPv4, dan gateway IPv4 hanya dapat diasosiasikan dengan satu VPC.
Anda tidak dapat membuat gateway IPv4 jika ada resource di VPC yang menggunakan mode transparan EIP.
Contohnya, jika gateway NAT Internet di VPC memiliki mode binding EIP diatur ke mode multi-EIP-ke-ENI, maka tidak kompatibel dengan gateway IPv4. Panggil ModifyNatGatewayAttribute untuk mengubah EipBindMode ke mode NAT agar kompatibel.
Dalam skenario VPC bersama, hanya pemilik resource yang dapat membuat, mengubah, atau menghapus gateway IPv4. Pengguna resource tidak memiliki izin tersebut.
Saat EIP atau Anycast EIP diasosiasikan dengan instance CLB yang menghadap privat:
- Di wilayah berikut, traffic akses Internet juga tunduk pada pembatasan gateway IPv4. Wilayah yang didukung dapat berubah sewaktu-waktu.
  Asia Pasifik - Tiongkok: Tiongkok (Hangzhou), Tiongkok (Shanghai), Tiongkok (Qingdao), Tiongkok (Hohhot), Tiongkok (Ulanqab), Tiongkok (Shenzhen), Tiongkok (Guangzhou), Tiongkok (Chengdu), Tiongkok (Hong Kong)
  Asia Pasifik - Lainnya: Jepang (Tokyo), Malaysia (Kuala Lumpur), Indonesia (Jakarta), Malaysia (Johor), Thailand (Bangkok), Filipina (Manila)
  Eropa dan Amerika: Inggris (London), Prancis (Paris), AS (Virginia), AS (Silicon Valley)
  Timur Tengah: SAU (Riyadh - Wilayah Mitra)
  - CLB yang menghadap privat yang di-deploy di vSwitch publik dapat mengakses Internet setelah mengasosiasikan alamat IP publik.
  - CLB yang menghadap privat yang di-deploy di vSwitch privat tidak dapat mengakses Internet meskipun memiliki alamat IP publik. Konfigurasikan rute yang mengarah ke gateway NAT Internet untuk mengarahkan traffic yang menuju Internet melalui gateway NAT tersebut dan gunakan alamat IP publik terkaitnya untuk akses Internet.
- Di wilayah lain, traffic akses Internet tidak tunduk pada pembatasan gateway IPv4.

Penagihan

Gateway IPv4 tidak dikenai biaya.

Biaya lalu lintas Internet dihasilkan oleh alamat IP publik terkait (seperti EIP atau alamat IP publik statis dari instans ECS/CLB). Lihat dokumentasi penagihan produk terkait.

Wilayah yang didukung

Area	Wilayah
Asia Pasifik - Tiongkok	Tiongkok (Hangzhou), Tiongkok (Shanghai), Tiongkok (Nanjing - Wilayah Lokal, Ditutup), Tiongkok (Qingdao), Tiongkok (Beijing), Tiongkok (Zhangjiakou), Tiongkok (Hohhot), Tiongkok (Ulanqab), Tiongkok (Shenzhen), Tiongkok (Heyuan), Tiongkok (Guangzhou), Tiongkok (Chengdu), Tiongkok (Zhongwei), Tiongkok (Hong Kong), Tiongkok (Wuhan - Wilayah Lokal), Tiongkok (Fuzhou - Wilayah Lokal, Ditutup)
Asia Pasifik - Lainnya	Jepang (Tokyo), Korea Selatan (Seoul), Singapura (Singapura), Malaysia (Kuala Lumpur), Indonesia (Jakarta), Filipina (Manila), Thailand (Bangkok), Malaysia (Johor)
Eropa & Amerika	Jerman (Frankfurt), Inggris (London), Prancis (Paris), AS (Silicon Valley), AS (Virginia), Meksiko, dan Brasil (São Paulo)
Timur Tengah	UEA (Dubai) dan SAU (Riyadh - Wilayah Mitra)

Kuota

Nama kuota	Deskripsi	Batas default	Dapat disesuaikan
Tidak ada	Jumlah maksimum gateway IPv4 per VPC.	1	Tidak
Tidak ada	Jumlah maksimum tabel rute gateway per gateway IPv4.	1	Tidak