Elastic Compute Service：Referensi Terraform

Fitur dasar Terraform

Terraform mendukung orkestrasi otomatis infrastruktur TI, memungkinkan Anda menggunakan kode untuk mengelola dan memelihara sumber daya TI. Untuk informasi lebih lanjut, lihat Apa itu Terraform?

• Terraform menyediakan CLI yang mudah digunakan untuk menerapkan file konfigurasi di Alibaba Cloud atau cloud pihak ketiga, serta mengelola versi file konfigurasi tersebut. Terraform memungkinkan Anda mendefinisikan sumber daya infrastruktur seperti mesin virtual (VM), akun penyimpanan, dan antarmuka jaringan dalam file konfigurasi.

• Terraform dapat diintegrasikan dengan penyedia Alibaba Cloud untuk mendukung infrastruktur baru. Anda dapat menggunakan template untuk mengonfigurasi penyedia Alibaba Cloud, mendefinisikan, meninjau, dan menerapkan infrastruktur cloud di Alibaba Cloud.

• Anda dapat menggunakan Terraform untuk membuat, memodifikasi, dan menghapus berbagai layanan Alibaba Cloud.

Untuk informasi tentang cara mengintegrasikan layanan Alibaba Cloud dengan Terraform, lihat Penyedia Alibaba Cloud.

Instal Terraform

terraform

echo $PATH

mv ~/Downloads/terraform /usr/local/bin/

git clone https://github.com/hashicorp/terraform.git

cd terraform

go install

echo $PATH

mv ~/Downloads/terraform /usr/local/bin/

brew tap hashicorp/tap

brew install hashicorp/tap/terraform

brew update

brew upgrade hashicorp/tap/terraform

yum install -y dnf-plugin-releasever-adapter
yum-config-manager --add-repo https://rpm.releases.hashicorp.com/RHEL/hashicorp.repo
yum install terraform

choco install terraform

Otentikasi Terraform

Anda dapat menyimpan kredensial akses di variabel lingkungan tertentu dan menggunakan variabel lingkungan tersebut untuk mengotentikasi Terraform. Saat menjalankan perintah Terraform, jika tidak ada kredensial akses yang dinyatakan secara eksplisit dalam template konfigurasi, Terraform dapat memperoleh kredensial akses dari variabel lingkungan. Konfigurasikan variabel lingkungan berdasarkan sistem operasi.

# Access Key Id
$ export ALICLOUD_ACCESS_KEY="yourAccessKeyID"
# Access Key Secret
$ export ALICLOUD_SECRET_KEY="yourAccessKeySecret"
# Jika Anda menggunakan token STS, atur variabel lingkungan ALICLOUD_SECURITY_TOKEN ke token STS.
$ export ALICLOUD_SECURITY_TOKEN="yourSTStoken"

Setelah mengonfigurasi variabel lingkungan, Anda tidak perlu mendeklarasikan kredensial akses secara eksplisit atau cukup mendeklarasikan ID wilayah di blok kode penyedia dalam template konfigurasi.

provider "alicloud" {
  region = "cn-hangzhou"
}

Anda juga dapat menentukan ID wilayah menggunakan variabel lingkungan ALICLOUD_REGION. Jika tidak ada ID wilayah yang dideklarasikan dan variabel lingkungan ALICLOUD_REGION tidak dikonfigurasi, cn-beijing digunakan sebagai nilai parameter wilayah.

Sumber daya yang didukung

Gunakan Terraform untuk membuat dan mengelola sumber daya ECS

Berikut ini menjelaskan cara membuat instans ECS menggunakan Terraform.

1. Buat direktori kerja dan file konfigurasi bernama main.tf di direktori tersebut. Kode berikut digunakan untuk membuat instans ECS serta virtual private cloud (VPC), grup keamanan, dan vSwitch yang diperlukan untuk membuat instans ECS. Salin kode berikut ke file konfigurasi main.tf:

   # Tentukan variabel bernama region untuk merepresentasikan wilayah Alibaba Cloud. Nilai default variabel ini adalah cn-beijing.
   variable "region"{
     default = "cn-beijing"
   }
   
   # Konfigurasikan penyedia Alibaba Cloud dan tentukan wilayah yang didefinisikan dalam variabel region.
   provider "alicloud"{
     region = var.region
   }
   
   # Tentukan variabel string bernama instance_type untuk merepresentasikan tipe instans ECS. Nilai default variabel ini adalah ecs.e-c1m1.large.
   variable "instance_type" {
     type    = string
     default = "ecs.e-c1m1.large"
   }
   
   # Gunakan sumber data dan konfigurasikan tipe instans yang ditentukan, tipe sumber daya (seperti vSwitch), dan kategori disk sebagai filter untuk menanyakan zona di mana Anda dapat membuat instans ECS.
   data "alicloud_zones" "default" {
     available_instance_type     = var.instance_type
     available_resource_creation = "VSwitch"
     available_disk_category     = "cloud_essd"
   }
   
   # Tentukan variabel bernama vpc_cidr_block untuk merepresentasikan blok CIDR yang ingin Anda asosiasikan dengan VPC. Nilai default variabel ini adalah 172.16.0.0/16.
   variable "vpc_cidr_block" {
     default = "172.16.0.0/16"
   }
   
   # Tentukan variabel bernama vsw_cidr_block untuk merepresentasikan blok CIDR yang ingin Anda asosiasikan dengan vSwitch. Nilai default variabel ini adalah 172.16.0.0/24.
   variable "vsw_cidr_block" {
     default = "172.16.0.0/24"
   }
   
   # Hasilkan bilangan bulat acak dari 10000 hingga 99999 untuk memastikan keunikan nama sumber daya tertentu.
   resource "random_integer" "default" {
     min = 10000
     max = 99999
   }
   
   # Buat VPC bernama vpc-test dan gunakan bilangan bulat acak untuk memastikan keunikan nama.
   resource "alicloud_vpc" "vpc" {
     vpc_name   = "vpc-test_${random_integer.default.result}"
     cidr_block = var.vpc_cidr_block
   }
   
   # Buat grup keamanan di VPC yang telah dibuat dan gunakan bilangan bulat acak untuk memastikan keunikan nama grup keamanan.
   resource "alicloud_security_group" "group" {
     security_group_name = "test_${random_integer.default.result}"  # Ganti test_$ dengan nilai sebenarnya.
     vpc_id              = alicloud_vpc.vpc.id
   }
   
   # Buat aturan grup keamanan masuk yang mengizinkan semua lalu lintas TCP dalam grup keamanan yang telah dibuat.
   resource "alicloud_security_group_rule" "allow_all_tcp" {
     type              = "ingress"
     ip_protocol       = "tcp"
     nic_type          = "intranet"  # Atur parameter nic_type menjadi 'intranet'.
     policy            = "accept"
     port_range        = "1/65535"
     priority          = 1
     security_group_id = alicloud_security_group.group.id
     cidr_ip           = "0.0.0.0/0"
   }
   
   # Buat vSwitch di zona yang ditentukan dan VPC yang telah dibuat, serta gunakan bilangan bulat acak untuk memastikan keunikan nama vSwitch.
   resource "alicloud_vswitch" "vswitch" {
     vpc_id       = alicloud_vpc.vpc.id
     cidr_block   = var.vsw_cidr_block
     zone_id      = data.alicloud_zones.default.zones[0].id
     vswitch_name = "vswitch-test-${random_integer.default.result}"
   }
   
   # Tentukan beberapa parameter, termasuk zona, grup keamanan, dan tipe instans, untuk membuat instans ECS dan gunakan bilangan bulat acak untuk memastikan keunikan nama instans.
   resource "alicloud_instance" "instance" {
     availability_zone          = data.alicloud_zones.default.zones[0].id
     security_groups            = [alicloud_security_group.group.id]
     instance_type              = var.instance_type
     system_disk_category       = "cloud_essd"
     system_disk_name           = "test_foo_system_disk_${random_integer.default.result}"
     system_disk_description    = "test_foo_system_disk_description"
     image_id                   = "aliyun_2_1903_x64_20G_alibase_20240628.vhd"
     instance_name              = "test_ecs_${random_integer.default.result}"
     vswitch_id                 = alicloud_vswitch.vswitch.id
     internet_max_bandwidth_out = 10
     password                   = "Terraform@Example" # Konfigurasikan kata sandi untuk instans ECS. Ganti Terraform@Example dengan nilai sebenarnya.
   }

2. Jalankan perintah berikut untuk menginisialisasi lingkungan runtime Terraform:

   terraform init

   Keluaran perintah berikut menunjukkan bahwa Terraform telah diinisialisasi:

   Terraform has been successfully initialized!
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. Jalankan perintah berikut untuk menjalankan kode:

   terraform apply

   Selama eksekusi kode, masukkan yes saat diminta dan tekan tombol Enter. Tunggu hingga eksekusi selesai. Keluaran perintah berikut menunjukkan bahwa kode telah dijalankan:

   You can apply this plan to save these new output values to the Terraform state, without changing any real infrastructure.
   
   Do you want to perform these actions?
     Terraform will perform the actions described above.
     Only 'yes' will be accepted to approve.
   
     Enter a value: yes
   
   
   Apply complete!  Resources: 6 added, 0 changed, 0 destroyed.

4. Verifikasi hasil

terraform show

Referensi

• Untuk informasi tentang studi kasus penggunaan Terraform, lihat Praktik Terbaik.

• Untuk informasi tentang perintah Terraform umum, lihat Perintah Umum.

• Terraform tersedia sebagai layanan terkelola di ROS. Anda dapat menerapkan template Terraform di konsol ROS. Untuk informasi lebih lanjut, lihat Buat Tumpukan Terraform.