Container Service for Kubernetes：Gunakan Terraform untuk mengaitkan set penyebaran dengan kolam node

Batasan

• alicloud_vpc: membuat VPC.

• alicloud_vswitch: membuat vSwitch dalam VPC untuk membuat subnet untuk VPC.

• alicloud_ecs_deployment_set: membuat set penyebaran.

• alicloud_cs_managed_kubernetes: membuat klaster ACK dikelola.

• alicloud_cs_kubernetes_node_pool: membuat kolam node untuk klaster ACK dikelola.

Gunakan Terraform untuk membuat kolam node dan mengaitkan set penyebaran dengan kolam node

1. Gunakan template berikut untuk membuat kolam node dan mengaitkan set penyebaran dengan kolam node:

   provider "alicloud" {
     region = var.region_id
   }
   
   variable "region_id" {
     type    = string
     default = "cn-shenzhen"
   }
   
   variable "name" {
     default = "tf-example"
   }
   
   variable "strategy" {
     default     = "Availability"
     description = "Strategi penyebaran. Nilai valid: Availability, AvailabilityGroup, LowLatency."
   }
   
   variable "cluster_spec" {
     type        = string
     description = "Spesifikasi klaster Kubernetes, yang bisa kosong. Nilai valid: ack.standard : Klaster dikelola standar; ack.pro.small : Klaster dikelola profesional."
     default     = "ack.pro.small"
   }
   
   # Tentukan zona vSwitches.
   variable "availability_zone" {
     description = "Zona ketersediaan vSwitches."
     default     = ["cn-shenzhen-c", "cn-shenzhen-e", "cn-shenzhen-f"]
   }
   
   # Blok CIDR yang digunakan untuk membuat vSwitches.
   variable "node_vswitch_cidrs" {
     type    = list(string)
     default = ["172.16.0.0/23", "172.16.2.0/23", "172.16.4.0/23"]
   }
   
   # Blok CIDR yang digunakan untuk membuat vSwitches Terway.
   variable "terway_vswitch_cidrs" {
     type    = list(string)
     default = ["172.16.208.0/20", "172.16.224.0/20", "172.16.240.0/20"]
   }
   
   # Tentukan tipe instance ECS dari node pekerja.
   variable "worker_instance_types" {
     description = "Tipe instance ECS yang digunakan untuk meluncurkan node pekerja."
     default     = ["ecs.g6.2xlarge", "ecs.g6.xlarge"]
   }
   
   # Tentukan kata sandi untuk node pekerja.
   variable "password" {
     description = "Kata sandi instance ECS."
     default     = "Test123456"
   }
   
   # Tentukan komponen yang ingin Anda instal di klaster ACK dikelola. Komponen termasuk Terway (plugin jaringan), csi-plugin (plugin volume), csi-provisioner (plugin volume), logtail-ds (plugin logging), controller NGINX Ingress, ack-arms-prometheus (plugin monitoring), dan ack-node-problem-detector (plugin diagnosa node).
   variable "cluster_addons" {
     type = list(object({
       name   = string
       config = string
     }))
   
     default = [
       {
         "name"   = "terway-eniip",
         "config" = "",
       },
       {
         "name"   = "logtail-ds",
         "config" = "{\"IngressDashboardEnabled\":\"true\"}",
       },
       {
         "name"   = "nginx-ingress-controller",
         "config" = "{\"IngressSlbNetworkType\":\"internet\"}",
       },
       {
         "name"   = "arms-prometheus",
         "config" = "",
       },
       {
         "name"   = "ack-node-problem-detector",
         "config" = "{\"sls_project_name\":\"\"}",
       },
       {
         "name"   = "csi-plugin",
         "config" = "",
       },
       {
         "name"   = "csi-provisioner",
         "config" = "",
       }
     ]
   }
   
   # Tentukan awalan nama klaster ACK dikelola.
   variable "k8s_name_prefix" {
     description = "Awalan nama yang digunakan untuk membuat klaster Kubernetes dikelola."
     default     = "tf-ack"
   }
   
   variable "vpc_name" {
     default = "tf-vpc"
   }
   variable "nodepool_name" {
     default = "default-nodepool"
   }
   
   # Nama sumber daya default.
   locals {
     k8s_name_terway = substr(join("-", [var.k8s_name_prefix, "terway"]), 0, 63)
   }
   
   # VPC.
   resource "alicloud_vpc" "default" {
     vpc_name   = var.vpc_name
     cidr_block = "172.16.0.0/12"
   }
   
   # vSwitches node.
   resource "alicloud_vswitch" "vswitches" {
     count      = length(var.node_vswitch_cidrs)
     vpc_id     = alicloud_vpc.default.id
     cidr_block = element(var.node_vswitch_cidrs, count.index)
     zone_id    = element(var.availability_zone, count.index)
   }
   
   # vSwitches pod.
   resource "alicloud_vswitch" "terway_vswitches" {
     count      = length(var.terway_vswitch_cidrs)
     vpc_id     = alicloud_vpc.default.id
     cidr_block = element(var.terway_vswitch_cidrs, count.index)
     zone_id    = element(var.availability_zone, count.index)
   }
   
   # Buat set penyebaran.
   resource "alicloud_ecs_deployment_set" "default" {
     strategy            = var.strategy
     domain              = "Default"
     granularity         = "Host"
     deployment_set_name = var.name
     description         = "example_value"
   }
   
   # Klaster ACK dikelola.
   resource "alicloud_cs_managed_kubernetes" "default" {
     name         = local.k8s_name_terway # Nama klaster ACK.
     cluster_spec = var.cluster_spec      # Buat klaster ACK Pro.
     worker_vswitch_ids           = split(",", join(",", alicloud_vswitch.vswitches.*.id))        # vSwitches yang digunakan oleh kolam node. Tentukan satu atau lebih ID vSwitch. vSwitches harus berada di zona yang ditentukan oleh availability_zone.
     pod_vswitch_ids              = split(",", join(",", alicloud_vswitch.terway_vswitches.*.id)) # vSwitches yang digunakan oleh pod.
     new_nat_gateway              = true                                                          # Tentukan apakah akan membuat NAT gateway saat klaster ACK dibuat. Nilai default: true.
     service_cidr                 = "10.11.0.0/16"                                                # Blok CIDR pod. Jika Anda mengatur parameter cluster_network_type ke flannel, parameter ini diperlukan. Blok CIDR pod tidak boleh sama dengan blok CIDR VPC atau blok CIDR klaster ACK lainnya di VPC. Anda tidak dapat mengubah blok CIDR pod setelah klaster dibuat. Jumlah maksimum host dalam klaster: 256.
     slb_internet_enabled         = true                                                          # Tentukan apakah akan membuat instance SLB yang menghadap internet untuk server API klaster. Nilai default: false.
     enable_rrsa                  = true
     control_plane_log_components = ["apiserver", "kcm", "scheduler", "ccm"] # Log kontrol plane.
   
     dynamic "addons" { # Manajemen komponen.
       for_each = var.cluster_addons
       content {
         name   = lookup(addons.value, "name", var.cluster_addons)
         config = lookup(addons.value, "config", var.cluster_addons)
       }
     }
   }
   
   # Kolam node reguler.
   resource "alicloud_cs_kubernetes_node_pool" "default" {
     cluster_id           = alicloud_cs_managed_kubernetes.default.id              # Nama klaster ACK.
     node_pool_name       = var.nodepool_name                                      # Nama kolam node.
     vswitch_ids          = split(",", join(",", alicloud_vswitch.vswitches.*.id)) # vSwitches yang digunakan oleh kolam node. Tentukan satu atau lebih ID vSwitch. vSwitches harus berada di zona yang ditentukan oleh availability_zone.
     instance_types       = var.worker_instance_types
     instance_charge_type = "PostPaid"
     runtime_name         = "containerd"
     desired_size          = 2            # Jumlah node yang diharapkan dalam kolam node.
     password              = var.password # Kata sandi yang digunakan untuk masuk ke klaster menggunakan SSH.
     install_cloud_monitor = true         # Tentukan apakah akan menginstal agen CloudMonitor pada node dalam klaster.
     system_disk_category  = "cloud_essd"
     system_disk_size      = 100
     image_type            = "AliyunLinux"
     deployment_set_id     = alicloud_ecs_deployment_set.default.id
   
     data_disks {              # Konfigurasi disk data node.
       category = "cloud_essd" # Kategori disk.
       size     = 120          # Ukuran disk.
     }
   }
   

2. Jalankan perintah berikut untuk menginisialisasi lingkungan runtime Terraform:

   terraform init

   Jika informasi berikut dikembalikan, Terraform telah diinisialisasi:

   Terraform has been successfully initialized!
   
   You may now begin working with Terraform. Try running "terraform plan" to see
   any changes that are required for your infrastructure. All Terraform commands
   should now work.
   
   If you ever set or change modules or backend configuration for Terraform,
   rerun this command to reinitialize your working directory. If you forget, other
   commands will detect it and remind you to do so if necessary.

3. Jalankan perintah berikut untuk membuat kolam node:

   terraform apply 

   Jika informasi berikut dikembalikan, kolam node telah dikaitkan dengan set penyebaran:

   Apakah Anda ingin melakukan tindakan ini?
     Terraform akan melakukan tindakan yang dijelaskan di atas.
     Hanya 'yes' yang akan diterima untuk menyetujui.
   
     Masukkan nilai: yes
   
   ...
   
   Apply complete! Resources: 10 ditambahkan, 0 diubah, 0 dihapus.

4. Verifikasi hasilnya

   Jalankan perintah terraform show

   Jalankan perintah berikut untuk memeriksa sumber daya yang dibuat oleh Terraform:

   terraform show

   

   Masuk ke konsol ACK

   Anda dapat menemukan kolam node yang Anda buat di halaman Node Pools di konsol ACK. Anda dapat mengklik Edit di kolom Actions untuk melihat set penyebaran yang terkait.

Contoh

provider "alicloud" {
  region = var.region_id
}

variable "region_id" {
  type    = string
  default = "cn-shenzhen"
}

variable "name" {
  default = "tf-example"
}

variable "strategy" {
  default     = "Availability"
  description = "Strategi penyebaran. Nilai valid: Availability, AvailabilityGroup, LowLatency."
}

variable "cluster_spec" {
  type        = string
  description = "Spesifikasi klaster Kubernetes, yang bisa kosong. Nilai valid: ack.standard : Klaster dikelola standar; ack.pro.small : Klaster dikelola profesional."
  default     = "ack.pro.small"
}

# Tentukan zona vSwitches.
variable "availability_zone" {
  description = "Zona ketersediaan vSwitches."
  default     = ["cn-shenzhen-c", "cn-shenzhen-e", "cn-shenzhen-f"]
}

# Blok CIDR yang digunakan untuk membuat vSwitches.
variable "node_vswitch_cidrs" {
  type    = list(string)
  default = ["172.16.0.0/23", "172.16.2.0/23", "172.16.4.0/23"]
}

# Blok CIDR yang digunakan untuk membuat vSwitches Terway.
variable "terway_vswitch_cidrs" {
  type    = list(string)
  default = ["172.16.208.0/20", "172.16.224.0/20", "172.16.240.0/20"]
}

# Tentukan tipe instance ECS dari node pekerja.
variable "worker_instance_types" {
  description = "Tipe instance ECS yang digunakan untuk meluncurkan node pekerja."
  default     = ["ecs.g6.2xlarge", "ecs.g6.xlarge"]
}

# Tentukan kata sandi untuk node pekerja.
variable "password" {
  description = "Kata sandi instance ECS."
  default     = "Test123456"
}

# Tentukan komponen yang ingin Anda instal di klaster ACK dikelola. Komponen termasuk Terway (plugin jaringan), csi-plugin (plugin volume), csi-provisioner (plugin volume), logtail-ds (plugin logging), controller NGINX Ingress, ack-arms-prometheus (plugin monitoring), dan ack-node-problem-detector (plugin diagnosa node).
variable "cluster_addons" {
  type = list(object({
    name   = string
    config = string
  }))

  default = [
    {
      "name"   = "terway-eniip",
      "config" = "",
    },
    {
      "name"   = "logtail-ds",
      "config" = "{\"IngressDashboardEnabled\":\"true\"}",
    },
    {
      "name"   = "nginx-ingress-controller",
      "config" = "{\"IngressSlbNetworkType\":\"internet\"}",
    },
    {
      "name"   = "arms-prometheus",
      "config" = "",
    },
    {
      "name"   = "ack-node-problem-detector",
      "config" = "{\"sls_project_name\":\"\"}",
    },
    {
      "name"   = "csi-plugin",
      "config" = "",
    },
    {
      "name"   = "csi-provisioner",
      "config" = "",
    }
  ]
}

# Tentukan awalan nama klaster ACK dikelola.
variable "k8s_name_prefix" {
  description = "Awalan nama yang digunakan untuk membuat klaster Kubernetes dikelola."
  default     = "tf-ack"
}

variable "vpc_name" {
  default = "tf-vpc"
}
variable "nodepool_name" {
  default = "default-nodepool"
}

# Nama sumber daya default.
locals {
  k8s_name_terway = substr(join("-", [var.k8s_name_prefix, "terway"]), 0, 63)
}

# VPC.
resource "alicloud_vpc" "default" {
  vpc_name   = var.vpc_name
  cidr_block = "172.16.0.0/12"
}

# vSwitches node.
resource "alicloud_vswitch" "vswitches" {
  count      = length(var.node_vswitch_cidrs)
  vpc_id     = alicloud_vpc.default.id
  cidr_block = element(var.node_vswitch_cidrs, count.index)
  zone_id    = element(var.availability_zone, count.index)
}

# vSwitches pod.
resource "alicloud_vswitch" "terway_vswitches" {
  count      = length(var.terway_vswitch_cidrs)
  vpc_id     = alicloud_vpc.default.id
  cidr_block = element(var.terway_vswitch_cidrs, count.index)
  zone_id    = element(var.availability_zone, count.index)
}

# Buat set penyebaran.
resource "alicloud_ecs_deployment_set" "default" {
  strategy            = var.strategy
  domain              = "Default"
  granularity         = "Host"
  deployment_set_name = var.name
  description         = "example_value"
}

# Klaster ACK dikelola.
resource "alicloud_cs_managed_kubernetes" "default" {
  name         = local.k8s_name_terway # Nama klaster ACK.
  cluster_spec = var.cluster_spec      # Buat klaster ACK Pro.
  worker_vswitch_ids           = split(",", join(",", alicloud_vswitch.vswitches.*.id))        # vSwitches yang digunakan oleh kolam node. Tentukan satu atau lebih ID vSwitch. vSwitches harus berada di zona yang ditentukan oleh availability_zone.
  pod_vswitch_ids              = split(",", join(",", alicloud_vswitch.terway_vswitches.*.id)) # vSwitch yang digunakan oleh pod.
  new_nat_gateway              = true                                                          # Tentukan apakah akan membuat NAT gateway saat klaster ACK dibuat. Nilai default: true.
  service_cidr                 = "10.11.0.0/16"                                                # Blok CIDR pod. Jika Anda mengatur parameter cluster_network_type ke flannel, parameter ini diperlukan. Blok CIDR pod tidak boleh sama dengan blok CIDR VPC atau blok CIDR klaster ACK lainnya di VPC. Anda tidak dapat mengubah blok CIDR pod setelah klaster dibuat. Jumlah maksimum host dalam klaster: 256.
  slb_internet_enabled         = true                                                          # Tentukan apakah akan membuat instance SLB yang menghadap internet untuk server API klaster. Nilai default: false.
  enable_rrsa                  = true
  control_plane_log_components = ["apiserver", "kcm", "scheduler", "ccm"] # Log kontrol plane.

  dynamic "addons" { # Manajemen komponen.
    for_each = var.cluster_addons
    content {
      name   = lookup(addons.value, "name", var.cluster_addons)
      config = lookup(addons.value, "config", var.cluster_addons)
    }
  }
}

# Kolam node reguler.
resource "alicloud_cs_kubernetes_node_pool" "default" {
  cluster_id           = alicloud_cs_managed_kubernetes.default.id              # Nama klaster ACK.
  node_pool_name       = var.nodepool_name                                      # Nama kolam node.
  vswitch_ids          = split(",", join(",", alicloud_vswitch.vswitches.*.id)) # vSwitches yang digunakan oleh kolam node. Tentukan satu atau lebih ID vSwitch. vSwitches harus berada di zona yang ditentukan oleh availability_zone.
  instance_types       = var.worker_instance_types
  instance_charge_type = "PostPaid"
  runtime_name         = "containerd"
  desired_size          = 2            # Jumlah node yang diharapkan dalam kolam node.
  password              = var.password # Kata sandi yang digunakan untuk masuk ke klaster menggunakan SSH.
  install_cloud_monitor = true         # Tentukan apakah akan menginstal agen CloudMonitor pada node dalam klaster.
  system_disk_category  = "cloud_essd"
  system_disk_size      = 100
  image_type            = "AliyunLinux"
  deployment_set_id     = alicloud_ecs_deployment_set.default.id

  data_disks {              # Konfigurasi disk data node.
    category = "cloud_essd" # Kategori disk.
    size     = 120          # Ukuran disk.
  }
}

Jika Anda ingin melihat contoh yang lebih lengkap, kunjungi Contoh Lainnya dan pilih direktori layanan cloud yang sesuai.

Referensi

• Untuk informasi lebih lanjut tentang cara mengontrol distribusi instance ECS dalam kolam node, lihat Praktik Terbaik untuk Mengaitkan Set Penyebaran dengan Kolam Node.

• Terraform tersedia sebagai layanan terkelola di ROS. Anda dapat menyebarkan template Terraform di konsol ROS. Untuk informasi lebih lanjut, lihat Buat Tumpukan Terraform.