Virtual Private Cloud:VPCs and vSwitches

Console

API

Unlike the console, the CreateVpc operation creates only an empty VPC. You must call the CreateVSwitch operation to create a vSwitch.

• Call CreateVpc and CreateVSwitch in sequence to create a VPC and a vSwitch.

• Call DeleteVSwitch and DeleteVpc in sequence to delete the vSwitch and the VPC.

  1. Before you delete a vSwitch, make sure the vSwitch is not shared, is not associated with a custom route table or a network ACL, and contains no cloud resources.

  2. Before you delete a VPC, make sure all resources in the VPC are released and the VPC is not associated with network services such as Cloud Enterprise Network (CEN).

Terraform

Resources: alicloud_vpc, alicloud_vswitch

Data Sources: alicloud_zones

# Specify the region where you want to create the VPC.
provider "alicloud" {
  region = "cn-hangzhou"
}

# Use a data source to automatically obtain a list of zones where you can create vSwitches.
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # Query the zones where vSwitches can be created in the VPC.
  # available_instance_type = "ecs.g7.large"  # Query the zones where ECS instances can be created in the VPC.
  # available_resource_creation = "slb"  # Query the zones where SLB instances can be created in the VPC.
}

# Create a VPC. 
resource "alicloud_vpc" "example_vpc" {
  vpc_name   = "example_vpc_name"
  cidr_block = "10.0.0.0/16" #Specify the CIDR block. 
}

# Create a vSwitch. 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name = "example_vswitch_name"
  cidr_block   = "10.0.0.0/24"                                  # Specify the CIDR block. 
  vpc_id       = alicloud_vpc.example_vpc.id                       # Specify the ID of the VPC to which the vSwitch belongs. 
  zone_id      = data.alicloud_zones.available_zones.zones.0.id # Specify the zone to which the vSwitch belongs.
}

Console

API

Unlike the console, an IPv6 Gateway is not created automatically when enabling IPv6 through the API. You must call CreateIpv6Gateway to create an IPv6 Gateway.

• When creating a VPC and a vSwitch, set the EnableIPv6 parameter in the CreateVpc and CreateVSwitch API calls to enable or disable IPv6. If you pass in Ipv6IpamPoolId and Ipv6CidrMask, an IPv6 CIDR block will be allocated from the IPv6 address pool to the VPC.

• For existing VPCs and vSwitches, modify the EnableIPv6 parameter of ModifyVpcAttribute and ModifyVSwitchAttribute to enable or disable IPv6. To allocate an IPv6 CIDR block from the IPv6 address pool to a VPC, call AssociateVpcCidrBlock.

Terraform

Terraform currently supports only system-assigned IPv6 CIDR blocks and does not yet support allocating from IPAM.

Resources: alicloud_vpc, alicloud_vswitch

Data Sources: alicloud_zones

# Specify the region where you want to create the VPC.
provider "alicloud" {
  region = "cn-hangzhou"
}

# Use a data source to automatically obtain a list of zones where you can create vSwitches.
data "alicloud_zones" "available_zones" {
  available_resource_creation = "VSwitch" # Query the zones where vSwitches can be created in the VPC.
  # available_instance_type = "ecs.g7.large"  # Query the zones where ECS instances can be created in the VPC.
  # available_resource_creation = "slb"  # Query the zones where SLB instances can be created in the VPC.
}

# Create a dual-stack VPC. 
resource "alicloud_vpc" "example_vpc" {
  vpc_name    = "example_vpc_name"
  cidr_block  = "10.0.0.0/16"
  enable_ipv6 = true  # Enable IPv6. Set the value to false to disable IPv6.
  ipv6_isp    = "BGP" # Specify the type of the IPv6 CIDR block.
}

# Create a dual-stack vSwitch. 
resource "alicloud_vswitch" "example_vswitch" {
  vswitch_name         = "example_vswitch_name"
  cidr_block           = "10.0.0.0/24"
  vpc_id               = alicloud_vpc.example_vpc.id
  zone_id              = data.alicloud_zones.available_zones.zones.0.id
  enable_ipv6          = true # Enable IPv6. Set the value to false to disable IPv6.
  ipv6_cidr_block_mask = 1    # Specify the last 8 bits of the IPv6 CIDR block for the vSwitch. 
} 

Console

API

• Call the CreateVSwitchCidrReservation operation to create a reserved CIDR block.

• Call the GetVSwitchCidrReservationUsage operation to view used IPs.

• Call the DeleteVSwitchCidrReservation operation to delete a reserved CIDR block.

Terraform

Resource: alicloud_vpc_vswitch_cidr_reservation

# Specify the region where you want to create the VPC.
provider "alicloud" {
  region = "cn-hangzhou" # The region where the resource resides.
}

# Specify the ID of the vSwitch.
variable "vsw_id" {
  default = "vsw-xxx" # Replace the value with the actual ID of the vSwitch.
}

# Create a reserved CIDR block.
resource "alicloud_vpc_vswitch_cidr_reservation" "example_cidr_reservation" {
  vswitch_id                    = var.vsw_id 
  ip_version                    = "IPv4" 
  cidr_reservation_cidr         = "10.0.0.128/26" # Specify the reserved CIDR block. 
}

Console

Before creating a VPC, ensure you have created an IPAM instance and pool in the IPAM console.

1. Go to the Create VPC page in the VPC console.

2. Configure IPv4 CIDR block: Choose the IPv4 CIDR block allocated by IPAM option. Select an IPAM pool and configure a mask. The system allocates the first available CIDR block that matches the length by default. You can select a different IPv4 CIDR block within the provisioned CIDR block of the pool.

3. Enable IPv6 (If necessary): Select IPv6 CIDR block allocated by IPAM. Choose an IPv6 IPAM pool, configure a mask or specify a IPv6 CIDR block.

API

• If you have created an IPAM pool, choose one of the following ways:

  • For IPv4 allocation: Call the CreateVpc operation and specify the IPAM pool using the Ipv4IpamPoolId parameter and specify a mask using the Ipv4CidrMask parameter. Alternatively, you can provide the CidrBlock parameter with the exact CIDR you want to use.

  • For IPv6 allocation: Provide both the Ipv6IpamPoolId and Ipv6CidrMask parameters in your CreateVpc call.

• If you have not created an IPAM pool, call the following operations in sequence to create an IPAM pool and then create a VPC.

  1. OpenVpcIpamService - Activate IPAM feature

  2. CreateIpam - Create an IPAM instance

  3. CreateIpamPool - Create an IPAM pool

  4. AddIpamPoolCidr - Provision a CIDR block for an IPAM pool

Terraform

Terraform currently only supports allocation IPv4 CIDR block from an IPAM pool. IPv6 allocation is not supported.

Resources: vpc_ipam_ipam, alicloud_vpc_ipam_ipam_pool, alicloud_vpc_ipam_ipam_pool_cidr, alicloud_vpc

# Specify the region where you want to create the IPAM instance, IPAM pool, and VPC.
provider "alicloud" {
  region = "cn-hangzhou"
}

# Create an IPAM instance.
resource "alicloud_vpc_ipam_ipam" "example_ipam" {
  ipam_name             = "example_ipam_name"
  operating_region_list = ["cn-hangzhou"] # Specify the region where the IPAM instance takes effect.
}

# Create an IPAM pool.
resource "alicloud_vpc_ipam_ipam_pool" "example_parentIpamPool" {
  ipam_scope_id  = alicloud_vpc_ipam_ipam.example_ipam.private_default_scope_id # Specify the scope of the IPAM pool.
  ipam_pool_name = "example_parentIpamPool_name"
  pool_region_id = alicloud_vpc_ipam_ipam.example_ipam.region_id # Specify the region where the IPAM pool takes effect.
  ip_version     = "IPv4"                                     # Specify the IP version of the IPAM pool.
}

# Allocate a CIDR block to the IPAM pool.
resource "alicloud_vpc_ipam_ipam_pool_cidr" "example_ipamPoolCidr" {
  cidr         = "10.0.0.0/16"                                       # Specify the CIDR block.
  ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # Specify the ID of the IPAM pool.
}

# Create a VPC.
resource "alicloud_vpc" "example_ipam_vpc" {
  vpc_name          = "example_ipam_vpc_name"
  ipv4_ipam_pool_id = alicloud_vpc_ipam_ipam_pool.example_parentIpamPool.id # Specify the ID of the IPAM pool.
  ipv4_cidr_mask    = 24                                                 # The IPv4 network mask.
}