Scenario examples

Synchronizes the result of remote authentication and sends the request URL as a header to the custom request API.

if eq(substr($uri, -4, -1), '.flv') {

    auth_addr = concat('http://xxx/sample/auth')

    req_info = []
    set(req_info, 'addr', auth_addr)
    set(req_info, 'retry', 1)
    set(req_info, 'timeout', 3000)
    set(req_info, 'method', 'POST')

    req_header_t = []
    set(req_header_t, 'Connection', 'close')
    set(req_header_t, 'Request-Url', $request_uri)
    set(req_info, 'send_headers' , req_header_t)

    rs = http_request(req_info)

    if rs {
        rscode = get(rs, 'code')
        if ne(rscode, 200) {
            exit(403)
        }
    }
}

• expires: the URL parameter, which defines the expiration time (Unix timestamp). This parameter value must be greater than the current server time.
• sign: the signature field. Rule to generate this field is: sign=md5($uri + $expires + $secret).

secret='abc'

if eq(substr($uri, -4, -1), '.flv') {

    if or(not($arg_sign), not($arg_expires)) {
        add_rsp_header('X-AUTH-MSG', 'auth failed - missing necessary arg')
        exit(403)
    }

    t = tonumber($arg_expires)
    if gt(now(), t) {
        add_rsp_header('X-AUTH-MSG', 'auth failed - expired url')
        exit(403)
    }

    digest = md5(concat($uri, $arg_expires, secret))
    if ne(digest, $arg_sign) {
        add_rsp_header('X-AUTH-MSG', 'auth failed - invalid sign')
        exit(403)
    }
}

The User-Agent blacklist feature.

The hyphens (-) in the request header need to be replaced with underscores (_). For example, X-USER-ID is replaced with x_user_id.

if eq(substr($uri, -4, -1), '.flv') {

    blacklist = []
    set(blacklist, 'black1', 1)
    set(blacklist, 'black2', 1)

    ua = req_header('user_agent')

    if eq(get(blacklist, ua), 1) {
        exit(403)
    }
}

Prohibits users originated from Singapore, Taiwan (China), Zhuhai, and China Telecom from streaming FLV content.

if eq(substr($uri, -4, -1), '.flv') {
    c_country = client_country()
    c_region = client_region()
    c_city = client_city()
    c_isp = client_isp()
    
    if eq(c_country, 'SG') {
        exit(403)
    }
  
    if eq(c_region, 'TW_01') {
        exit(403)
    }
  
    if eq(tonumber(c_city), 440400) {
        exit(403)
    }
  
    if eq(tonumber(c_isp), 100017) {
        exit(403)
    }
}

Add a suffix to the URI based on the pattern parameter. Example:

pattern = 1, uri = /test/live.flv --> /test/live1.flv

if eq(substr($uri, -4, -1), '.flv') {
    if $arg_pattern {
        dst = concat(substr($uri, 1, -5), $arg_pattern, '.flv')
        rewrite(dst, 'break')
    }
}

• Request URL format: /path/digest/?.ts?key=&t=.
• For .ts requests, the requirements for customizing hotlink protection are:
  • Rule 1: If the request does not contain the t or key parameter, the CDN edge node returns the HTTP 403 status code and adds the X-AUTH-MSG response header to indicate the failure cause.
  • Rule 2: The t parameter specifies the expiration time. If the specified t parameter is earlier than the current time, the CDN edge node returns the HTTP 403 status code and adds the X-AUTH-MSG response header to indicate the failure cause.
  • Rule 3: The CDN edge node compares the md5 parameter with the digest parameter. If md5 does not match digest, the CDN edge node returns the HTTP 403 status code.

    Value format of the md5 parameter: Private key + Path + Filename.extension.

if eq(substr($uri, -3, -1), '.ts') {

   if or(not($arg_t), not($arg_key)) {
       add_rsp_header('X-AUTH-MSG', 'auth failed - missing necessary arg')
       exit(403)
   }

   t = tonumber($arg_t)
   if not(t) {
       add_rsp_header('X-AUTH-MSG', 'auth failed - invalid time')
       exit(403)
   }

   if gt(now(), t) {
       add_rsp_header('X-AUTH-MSG', 'auth failed - expired url')
       exit(403)
   }

    pcs = capture_re($request_uri,'^/([^/]+)/([^/]+)/([^?]+)\?(.*)')
    sec1 = get(pcs, 1)
    sec2 = get(pcs, 2)
    sec3 = get(pcs, 3)

    if or(not(sec1), not(sec2), not(sec3)) {
        add_rsp_header('X-AUTH-MSG', 'auth failed - malformed url')
        exit(403)
    }

    key = 'b98d643a-9170-4937-8524-6c33514bbc23'
    signstr = concat(key, sec1, sec3)
    digest = md5(signstr)
    if ne(digest, sec2) {
        add_rsp_header('X-AUTH-DEBUG', concat('signstr: ', signstr))
        add_rsp_header('X-AUTH-MSG', 'auth failed - invalid digest')
        exit(403)
    }

}

• Requirements

  Enable Alibaba Cloud CDN to rewrite /hello to /index.html. As a result, the URI of the back-to-origin request is changed to /index.html and the parameters remain unchanged.

• Corresponding EdgeScript script:

  if match_re($uri, '^/hello$') {
      rewrite('/index.html', 'break')
  }

• Requirements

  Enable Alibaba Cloud CDN to rewrite /1.txt to /1<url parameter type>. For example, /1.txt?type=mp4 is rewritten to /1.mp4?type=mp4 in back-to-origin requests and cached on CDN edge nodes.

• Corresponding EdgeScript script:

  if and(match_re($uri, '^/1.txt$'), $arg_type) {
       rewrite(concat('/1.', $arg_type), 'break')
  }

• Requirements

  Convert a URI string to lowercase letters.

• Corresponding EdgeScript script:

  pcs = capture_re($uri, '^(.+%.)([^.]+)')
  section = get(pcs, 1)
  postfix = get(pcs, 2)
  
  if and(section, postfix) {
      rewrite(concat(section, lower(postfix)), 'break')
  }

• Requirements

  Enable Alibaba Cloud CDN to rewrite ^/nn_live/(.*) to /3rd/nn_live/$1.

• Corresponding EdgeScript script:

  pcs = capture_re($uri, '^/nn_live/(.*)')
  sec = get(pcs, 1)
  
  if sec {
       dst = concat('/3rd/nn_live/', sec)
       rewrite(dst, 'break')
  }

• Requirements

  Perform a 302 redirect from the / root directory to /app/movie/pages/index/index.html.

• Corresponding EdgeScript script:

  if eq($uri, '/') {
      rewrite('/app/movie/pages/index/index.html', 'redirect')
  }

• Requirements
  Redirect the following URIs that match the ^/$ root directory to https://demo.aliyundoc.com/index.html. You can specify the final URI as needed.

  • http://demo.aliyundoc.com
  • https://demo.aliyundoc.com
• Corresponding EdgeScript script:

  if eq($uri, '/') {
      rewrite('https://demo.aliyundoc.com/index.html', 'redirect')
  }